// System: Nugget
// modification: in case of an EC pair is equal select the first (*)
// own assumption: win and lost borader, unit bet table

/* Haftungsausschluss / Disclaimer
   Eine Haftung fuer die Richtigkeit der Implementierung des Systems wird NICHT uebernommen, der Download und
   der Einsatz des Systems erfolgt auf eigenes Risiko!
   A liability for the correctness of the implementation of the system will NOT be assumed, the download and use
   of the system is at your own risk!
   Ing. Thomas Froehlich (www.ing-froehlich.de)
*/

ST:
MESSAGE OFF;
SZ EI1(1);
SZ STMAX(I(1));
SZ STMAX(V(100),G(30),N);                                  // set lost and win border, restart if reached
SZ CO10(9);                                                // Coup Counter - collect data over 10 coups 

SZ ST1(8,4,2,1);                                           // setup unit bet table for the first EC
SZ ST2(8,4,2,1);                                           // setup unit bet table for the second EC
SZ ST3(8,4,2,1);                                           // setup unit bet table for the third EC

SZ CO01(0),CO02(0),CO03(0),CO04(0),CO05(0),CO06(0);        // Simple chance counter
SZ CO11(1),CO12(1),CO13(1);

SZ CO30(0);                                                // 0 - collect data, 1 - play data
SZ CO40(0);                                                // 0 - do not calculate bet, 1 - calculate bet 

AL:
IF CO30(0) AND IF GZ IN EC01 THEN SZ CO01(+1);             // 1-18
IF CO30(0) AND IF GZ IN EC06 THEN SZ CO06(+1);             // 19-36
IF CO30(0) AND IF GZ IN EC02 THEN SZ CO02(+1);             // EVEN
IF CO30(0) AND IF GZ IN EC05 THEN SZ CO05(+1);             // ODD
IF CO30(0) AND IF GZ IN EC03 THEN SZ CO03(+1);             // RED
IF CO30(0) AND IF GZ IN EC04 THEN SZ CO04(+1);             // BLACK
IF CO30(0) THEN SZ CO10(-1);                               // decrement coup counter

IF CO30(0) AND IF CO10(0) THEN SZ CO30(1);                 // statistic data is collected -determine which EC should be played

IF CO30(1) AND IF CO01(>CO06) THEN SZ PT1(EC06);
IF CO30(1) AND IF CO06(>CO01) THEN SZ PT1(EC01);
IF CO30(1) AND IF CO06(CO01) THEN SZ PT1(EC01);            // *

IF CO30(1) AND IF CO02(>CO05) THEN SZ PT1(EC05);
IF CO30(1) AND IF CO05(>CO02) THEN SZ PT1(EC02);
IF CO30(1) AND IF CO05(CO02) THEN SZ PT1(EC02);            // *

IF CO30(1) AND IF CO03(>CO04) THEN SZ PT1(EC04);
IF CO30(1) AND IF CO04(>CO03) THEN SZ PT1(EC03);
IF CO30(1) AND IF CO04(CO03) THEN SZ PT1(EC03);            // *

// IF CO30(1) THEN MESSAGE(PT1(1..3));                     // check which EC should be played

IF CO30(1) THEN SZ CO30(2);                                // EC which should be played is fixed -> next step

IF CO40(1) AND IF GZ IN AG(1) THEN SZ CO11(-1);            // determine stage in the unit bet table
IF CO40(1) AND IF GZ NOT IN AG(1) THEN SZ CO11(+1);
IF CO11(5) THEN SZ CO11(4);
IF CO11(0) THEN SZ CO11(1);

IF CO40(1) AND IF GZ IN AG(2) THEN SZ CO12(-1);
IF CO40(1) AND IF GZ NOT IN AG(2) THEN SZ CO12(+1);
IF CO12(5) THEN SZ CO12(4);
IF CO12(0) THEN SZ CO12(1);

IF CO40(1) AND IF GZ IN AG(3) THEN SZ CO13(-1);
IF CO40(1) AND IF GZ NOT IN AG(3) THEN SZ CO13(+1);
IF CO13(5) THEN SZ CO13(4);
IF CO13(0) THEN SZ CO13(1);

IF CO30(2) THEN SZ EI1(ST1(CO11)),PT1(1);                  // set bet and play EC from the playtable
IF CO30(2) THEN SZ EI1(ST2(CO12)),PT1(2);
IF CO30(2) THEN SZ EI1(ST3(CO13)),PT1(3),CO40(1);          // and on the last activate for the next run calculate bet stage